エクセル2013基本講座：ユーザーフォームを使って入力する

ユーザーフォームを使って入力する　　　　　Topへ

ここでは、Excel2013でフォーム機能を使う　で利用したフォームを使いやすいように改良してみたいと思います。
フォームを使うでは、住所録を入力する際に下図のようなフォームが表示されました。
ここでは、下図のように作成したユーザーフォームから入力するようにしてみます。
- サンプルファイルはExcel2013で作成しています。　HP_2013_userform.xlsm
ユーザーフォームを作成してみます。
1. [Alt]+[F11]でVBEを開きます。
2. [ユーザーフォームの挿入]を実行します。
3. 下図のようにツールボックスの「ラベル」「テキストボックス」「コンボボックス」「コマンドボタン」を配置します。
4. 下図がユーザーフォームを挿入して、「ラベル」「テキストボックス」「コンボボックス」「コマンドボタン」を配置した状態です。
  - 表示している文字はそれぞれのプロパティウィンドウのCaptionで変更できます。

コードを作成します。

コンボボックス1には入力済みの連番、コンボボックス2では「男」と「女」が選択できるようにしました。

Private Sub UserForm_Initialize()
　　Dim lRow As Long
　　　　With Worksheets("Sheet1")
　　　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　End With
　　　　With ComboBox1
　　　　　　.RowSource = "Sheet1!B3:B" & lRow
　　　　End With
　　　　With ComboBox2
　　　　　　.AddItem "男"
　　　　　　.AddItem "女"
　　　　End With
End Sub

連番(コンボボックス1)では入力済みの連番を選択するか、新しい連番を入力するようにしてみます。
ComboBox1_afterupdate()　とデータが更新されたら表示を変えるようにしていますので、他のテキストボックスを選択するなどしてコンボボックスの値が更新された時に反応するようにしています。

Private Sub ComboBox1_afterupdate()
　　Dim lRow As Long
　　Dim i As Integer
　　Dim myFlag As Boolean
　　Dim myRow As Long
　　Dim myNo As Variant

　　If ComboBox1.Value = "" Then
　　　　TextBox1.Value = ""
　　　　TextBox2.Value = ""
　　　　TextBox3.Value = ""
　　　　TextBox4.Value = ""
　　　　TextBox5.Value = ""
　　　　ComboBox2.Value = ""
　　　　Exit Sub
　　End If

　　'シートに連番が入力済みか否かを調べる
　　With Worksheets("Sheet1")
　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　myNo = .Range("B3:B" & lRow).Value
　　　　myFlag = False

　　　　For i = LBound(myNo) To UBound(myNo)
　　　　　　If CInt(myNo(i, 1)) = CInt(ComboBox1.Value) Then
　　　　　　　　myFlag = True
　　　　　　　　myRow = i + 2
　　　　　　　　Exit For
　　　　　　End If
　　　　Next i

　　　　'既に入力されていたら、入力済みのデータを表示する
　　　　If myFlag = True Then
　　　　　　TextBox1.Value = .Range("C" & myRow)
　　　　　　TextBox2.Value = .Range("D" & myRow)
　　　　　　TextBox3.Value = .Range("F" & myRow)
　　　　　　TextBox4.Value = .Range("G" & myRow)
　　　　　　TextBox5.Value = .Range("H" & myRow)
　　　　　　ComboBox2.Value = .Range("E" & myRow)
　　　　Else
　　　　　　TextBox1.Value = ""
　　　　　　TextBox2.Value = ""
　　　　　　TextBox3.Value = ""
　　　　　　TextBox4.Value = ""
　　　　　　TextBox5.Value = ""
　　　　　　ComboBox2.Value = ""
　　　　End If
　　End With

End Sub

実行例
コンボボックス1で連番を選択して、氏名のテキストボックスを選択すると、下図のように連番と一致するデータが表示されます。
コンボボックス1の値がシートの連番と一致していないときは、ユーザーフォームを空欄になります。

コマンドボタン1　[登録]ボタンではデータを転記します。
コマンドボタン2　[終了]ボタンではユーザーフォームを閉じます。

Private Sub CommandButton1_Click()
　　Dim lRow As Long
　　Dim i As Integer
　　Dim myFlag As Boolean
　　Dim myRow As Long
　　Dim myNo As Variant

　　If ComboBox1.Value = "" Or IsNumeric(ComboBox1.Value) = False Then
　　　　MsgBox "連番には数値を入力してください"
　　　　Exit Sub
　　End If

　　With Worksheets("Sheet1")
　　　　lRow = .Range("B" & Rows.Count).End(xlUp).Row
　　　　myNo = .Range("B3:B" & lRow).Value
　　　　myFlag = False
　　　　For i = LBound(myNo) To UBound(myNo)
　　　　　　If CInt(myNo(i, 1)) = CInt(ComboBox1.Value) Then
　　　　　　　　myFlag = True
　　　　　　　　myRow = i + 2
　　　　　　　　Exit For
　　　　　　End If
　　　　Next i

　　　　If myFlag = False Then myRow = lRow + 1
　　　　　　.Range("B" & myRow).Value = ComboBox1.Value
　　　　　　.Range("C" & myRow).Value = TextBox1.Value
　　　　　　.Range("D" & myRow).Value = TextBox2.Value
　　　　　　.Range("E" & myRow).Value = ComboBox2.Value
　　　　　　.Range("F" & myRow).Value = TextBox3.Value
　　　　　　.Range("G" & myRow).Value = TextBox4.Value
　　　　　　.Range("H" & myRow).Value = TextBox5.Value

　　End With
End Sub

’------------------------
Private Sub CommandButton2_Click()
　　　　Unload UserForm1
End Sub

ちなみに、ユーザーフォームの表示は標準モジュールに下記のようなコードを書いています。
- コードの例
  
  Sub start1()
  　　UserForm1.Show vbModeless
  End Sub

よねさんのExcelとWordの使い方｜エクセル2013基本講座：目次｜データ/数式/関数の入力｜ユーザーフォームを使って入力する

エクセル2013基本講座：ユーザーフォームを使って入力する

ユーザーフォームを使って入力する Topへ

コードを作成します。

ユーザーフォームを使って入力する　　　　　Topへ